Back to Main page.
Back to Main tapes page.
1000  REM: ***** Craps
1005  GOSUB 8000
1010  A=100
1020  FOR X=1 TO 10
1030  PRINT  USING 1040;A
1040  IMAGE#,"You have $",4d.2d,"   Your bet"
1050  GOSUB 100
1060  INPUT B
1065  IF B<0 THEN 130
1070  IF B<.01 OR B>A THEN 1340
1080  DEF FNB(X)=INT(10*RND(0))
1090  C=FNB(X)
1100  D=FNB(X)
1110  IF C<1 OR D<1 OR C>6 OR D>6 THEN 1090
1120  PRINT  USING 1200;C,D,D+C
1130  IF C+D=7 OR C+D=11 THEN 1260
1140  IF C+D=2 OR C+D=3 OR C+D=12 THEN 1230
1150  PRINT "Point"'7"!"'7"!"
1160  E=FNB(X)
1170  F=FNB(X)
1180  IF E<1 OR F<1 OR E>6 OR F>6 THEN 1160
1190  PRINT  USING 1200;E,F,E+F
1200  IMAGE"Rolled a",3d," and a",3d,"   Total =",5d
1210  IF F+E=C+D THEN 1260
1220  IF E+F#7 THEN 1160
1230  PRINT "You lose"'10
1240  A=A-B
1250  GOTO 1280
1260  PRINT "You win"'10
1270  A=A+B
1280  IF  NOT A THEN 1320
1290  NEXT X
1300  PRINT "No fair, you're a professional Craps player - goodbye."
1310  GOTO 130
1320  PRINT "I guess that means that you are broke."
1330  GOTO 130
1340  PRINT "You must bet between one cent ($.01) and $";A
1350  GOTO 1030
1360  END 
8000  REM *** This section was written by Lane Rollins.
8010  DIM Z1$[10]
8020  PRINT "Instructions: ";
8030  LINPUT Z1$
8040  IF Z1$[1,1]="N" THEN 8130
8050  PRINT ""
8060  PRINT "    MAKE A BET FROM ONE CENT (.01) TO THE AMOUNT OF MONEY THAT YOU"
8070  PRINT "HAVE.  TO WIN YOU MUST HAVE A 7 OR AN 11 ON YOUR FIRST ROLL"
8080  PRINT "OF THE DICE, OR YOU MUST GET THE SAME NUMBER ON ONE OF YOUR"
8090  PRINT "FOLLOWING ROLLS.  IF YOU ROLL A 7 BEFORE YOU GET YOUR NUMBER,"
8100  PRINT "YOU LOSE YOUR BET.  ROLLING A 2, 3 OR 12 ON YOUR FIRST ROLL IS AN"
8110  PRINT "AUTOMATIC LOSS."
8120  PRINT ""
8125  PRINT "A BET OF -1 WILL END THE GAME."
8127  PRINT 
8130  RETURN 
8140  END