Back to Main page.
Back to Main tapes page.
10  REM:BY BILL MCFADDEN-COMPLETED 5-17-77
20  REM:ALL RIGHTS RESERVED
30  REM:ALL PURPOSE CONVERSION PROG.
40  FILES CONVER.B952,NOLIST.B952
50  IF TYP(2)=3 THEN 90
60  ADVANCE #2;1,F
70  GOTO 50
80  DIM A$[72],B$[72],C$[72],D$[72]
90  REM:INPUT CONVERSIONS
100  PRINT "* ";
110  READ #1,1
120  LINPUT C$
130  CHAIN E,C$
140  A$=""
150  B$=""
160  B=0
170  IF C$="" THEN 810
180  REM:FILTER C$
190  C$=UPS$(C$)
200  FOR E=1 TO LEN(C$)
210  F=NUM(C$[E,E])
220  IF F>45 AND F<91 OR F=44 THEN 240
230  C$[E,E]=" "
240  NEXT E
250  REM:DETERMINE B,A$,B$
260  FOR X=1 TO LEN(C$)
270  F=NUM(C$[X,X])
280  IF F>57 OR F<46 AND F#32 THEN 310
290  CONVERT C$[1,X] TO B
300  NEXT X
310  FOR Y=X TO LEN(C$)
320  IF C$[Y,Y]="," THEN 370
330  A$[1,Y-X+1]=C$[X,Y+1]
340  NEXT Y
350  Y=Y-1
360  GOTO 380
370  B$=C$[Y+1,LEN(C$)]
380  IF A$="LIST" THEN 560
390  IF A$="" THEN 100
400  IF B=0 AND NUM(B$)#0 THEN 100
410  IF B#0 AND NUM(B$)=0 THEN 100
420  REM:SEARCH FOR CONVERSION
430  IF  END #1 THEN 750
440  READ #1;C$,D$,D
450  IF A$#C$ THEN 440
460  IF B$="" THEN 530
470  IF B$#D$ THEN 440
480  REM:CONVERT
490  E=B*D
500  PRINT LIN(1);B;A$" ="E;B$;LIN(-1)
510  GOTO 100
520  REM:LIST FOR SINGLE CONVERSION
530  PRINT "TO "D$
540  GOTO 440
550  REM:CONVERSION LIST
560  PRINT TAB(22)"CONVERSION"TAB(55)"MULTIPLY BY"








570  FOR X=1 TO 65
580  PRINT "-";
590  NEXT X
600  PRINT 
610  IF  END #1 THEN 690
620  E=0
630  READ #1;C$,D$,D
640  E=E+1
650  PRINT C$;TAB(23)" TO "D$;TAB(55);D
660  IF INT(E/5)#E/5 THEN 630
670  PRINT 
680  GOTO 630
690  PRINT LIN(-2)"TOTAL="E"ENTRIES"LIN(-2)
700  FOR X=1 TO 65
710  PRINT "-";
720  NEXT X
730  PRINT LIN(-30)
740  STOP 
750  REM:NOT FOUND
760  IF B$="" THEN 100
770  PRINT '34A$" TO "B$'34" IS NOT ON FILE."
780  IF  END #2 THEN 100
790  PRINT #2;A$,B$
800  GOTO 100
810  END