Back to Main page.
Back to Main tapes page.
10  REM*****BY BILL MCFADDEN ON 1/13/77*****
20  REM*****ALL RIGHTS RESERVED*****
30  REM*****LAST ACCESS 1/13/77*****
40  REM*****CONVERTS UNITS TO UNITS*****
50  FILES CONVER.B952,NOLIST.B952
60  IF TYP(2)=3 THEN 100
70  ADVANCE #2;1,F
80  GOTO 60
90  DIM A$[72],B$[72],C$[72],D$[72]
100  REM*****INPUT CONVERSIONS*****
110  PRINT "CONVERT: ";
120  READ #1,1
130  LINPUT A$
140  FOR E=1 TO LEN(A$)
150  IF A$[E,E]#"-" THEN 170
160  A$[E,E]=" "
170  NEXT E
180  IF A$="" THEN 630
190  IF A$="LIST" THEN 450
200  PRINT "CONVERT "A$" TO : ";
210  LINPUT B$
220  FOR E=1 TO LEN(B$)
230  IF B$[E,E]#"-" THEN 250
240  B$[E,E]=" "
250  NEXT E
260  IF B$="" THEN 110
270  IF B$="?" THEN 310
280  PRINT "HOW MANY "A$;
290  INPUT B
300  REM*****SEARCH FILE FOR CONVERSION*****
310  IF  END #1 THEN 580
320  REM
330  READ #1;C$,D$,D
340  IF A$#C$ THEN 320
350  IF B$="?" THEN 380
360  IF B$#D$ THEN 320
370  GOTO 410
380  PRINT "TO "D$
390  GOTO 330
400  REM*****CONVERT AND PRINT*****
410  E=B*D
420  PRINT LIN(1);B;A$" ="E;B$;LIN(-1)
430  GOTO 110
440  REM*****PRINT CONVERSION LIST*****
450  PRINT LIN(-10);TAB(22)"CONVERSION"TAB(55)"MULTIPLY BY"
460  PRINT "-----------------------------------------------------------------"
470  IF  END #1 THEN 550
480  E=0
490  READ #1;C$,D$,D
500  E=E+1
510  PRINT C$;TAB(23)" TO "D$;TAB(55);D
520  IF INT(E/5)#E/5 THEN 490
530  PRINT 
540  GOTO 490
550  PRINT LIN(-2)"TOTAL="E"ENTRIES"LIN(-2)
560  PRINT "----------------------------------------------------------------"LIN(-10);'13
570  STOP 
580  REM*****CONVERSION NOT FOUND*****
590  IF B$="?" THEN 110
600  PRINT "CONVERSION IS NOT ON FILE"
610  PRINT #2;A$,B$
620  GOTO 110
630  END